ZigbeePowerOutlet

About

The ZigbeePowerOutlet class provides a smart power outlet endpoint for Zigbee networks. This endpoint implements the Zigbee Home Automation (HA) standard for power control, allowing remote on/off control of electrical devices.

Features: * On/off power control * State change callbacks

API Reference

Constructor

ZigbeePowerOutlet

Creates a new Zigbee power outlet endpoint.

ZigbeePowerOutlet(uint8_t endpoint);

endpoint - Endpoint number (1-254)

Power Control

setState

Sets the power outlet state (on or off).

bool setState(bool state);

state - true to turn on, false to turn off

This function will return true if successful, false otherwise.

getPowerOutletState

Gets the current power outlet state.

bool getPowerOutletState();

This function will return current power state (true = on, false = off).

restoreState

Restores the power outlet state and triggers any registered callbacks.

void restoreState();

Event Handling

onPowerOutletChange

Sets a callback function to be called when the power outlet state changes.

void onPowerOutletChange(void (*callback)(bool));

callback - Function to call when power outlet state changes

Example

Smart Power Outlet Implementation

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at

//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

/**
 * @brief This example demonstrates simple Zigbee power outlet.
 *
 * The example demonstrates how to use Zigbee library to create a end device power outlet.
 * The power outlet is a Zigbee end device, which is controlled by a Zigbee coordinator.
 *
 * Proper Zigbee mode must be selected in Tools->Zigbee mode
 * and also the correct partition scheme must be selected in Tools->Partition Scheme.
 *
 * Please check the README.md for instructions and more detailed description.
 *
 * Created by Ludovic Boué (https://github.com/lboue)
 */

#ifndef ZIGBEE_MODE_ZCZR
#error "Zigbee router mode is not selected in Tools->Zigbee mode"
#endif

#include "Zigbee.h"

/* Zigbee power outlet configuration */
#define ZIGBEE_OUTLET_ENDPOINT 1

#ifdef LED_BUILTIN  // Use built-in LED if defined for the board
uint8_t led = LED_BUILTIN;
#else
uint8_t led = 2;  // Use custom LED pin
#endif

uint8_t button = BOOT_PIN;

ZigbeePowerOutlet zbOutlet = ZigbeePowerOutlet(ZIGBEE_OUTLET_ENDPOINT);

/********************* RGB LED functions **************************/
void setLED(bool value) {
  digitalWrite(led, value);
}

/********************* Arduino functions **************************/
void setup() {
  Serial.begin(115200);

  // Init LED and turn it OFF (if LED_PIN == RGB_BUILTIN, the rgbLedWrite() will be used under the hood)
  pinMode(led, OUTPUT);
  digitalWrite(led, LOW);

  // Init button for factory reset
  pinMode(button, INPUT_PULLUP);

  //Optional: set Zigbee device name and model
  zbOutlet.setManufacturerAndModel("Espressif", "ZBPowerOutlet");

  // Set callback function for power outlet change
  zbOutlet.onPowerOutletChange(setLED);

  //Add endpoint to Zigbee Core
  Serial.println("Adding ZigbeePowerOutlet endpoint to Zigbee Core");
  Zigbee.addEndpoint(&zbOutlet);

  // When all EPs are registered, start Zigbee. By default acts as ZIGBEE_END_DEVICE
  if (!Zigbee.begin(ZIGBEE_ROUTER)) {
    Serial.println("Zigbee failed to start!");
    Serial.println("Rebooting...");
    ESP.restart();
  }
  Serial.println("Connecting to network");
  while (!Zigbee.connected()) {
    Serial.print(".");
    delay(100);
  }
  Serial.println();
}

void loop() {
  // Checking button for factory reset
  if (digitalRead(button) == LOW) {  // Push button pressed
    // Key debounce handling
    delay(100);
    int startTime = millis();
    while (digitalRead(button) == LOW) {
      delay(50);
      if ((millis() - startTime) > 3000) {
        // If key pressed for more than 3secs, factory reset Zigbee and reboot
        Serial.println("Resetting Zigbee to factory and rebooting in 1s.");
        delay(1000);
        Zigbee.factoryReset();
      }
    }
    // Toggle state by pressing the button
    zbOutlet.setState(!zbOutlet.getPowerOutletState());
  }
  delay(100);
}