MatterContactSensor

About

The MatterContactSensor class provides a contact sensor endpoint for Matter networks. This endpoint implements the Matter contact sensing standard for detecting open/closed states (e.g., doors, windows).

Features: * Contact state reporting (open/closed) * Simple boolean state * Read-only sensor (no control functionality) * Automatic state updates * Integration with Home Assistant, Apple Home, Amazon Alexa, and Google Home * Matter standard compliance

Use Cases: * Door/window sensors * Contact switches * Security systems * Access control * Smart home automation triggers

API Reference

Constructor

MatterContactSensor

Creates a new Matter contact sensor endpoint.

MatterContactSensor();

Initialization

begin

Initializes the Matter contact sensor endpoint. Fabric StateValue starts false (open). Call setContact() after Matter.begin() with the real sensor reading.

bool begin();

This function will return true if successful, false otherwise.

Typical usage:

ContactSensor.begin();
Matter.begin();
ContactSensor.setContact(digitalRead(contactPin));

end

Stops processing Matter contact sensor events.

void end();

Contact State Control

setContact

Sets the contact state. Call after Matter.begin().

bool setContact(bool _contactState);

_contactState - Contact state (true = closed, false = open)

This function will return true if successful, false otherwise.

getContact

Gets the current contact state.

bool getContact();

This function will return true if closed, false if open.

Operators

bool operator

Returns the current contact state.

operator bool();

Example:

if (mySensor) {
    Serial.println("Contact is closed");
} else {
    Serial.println("Contact is open");
}

Assignment operator

Sets the contact state. Same as setContact(); call after Matter.begin().

void operator=(bool _contactState);

Example:

mySensor = true;   // Set contact to closed
mySensor = false;  // Set contact to open

Example

Contact Sensor

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

/*
 * This example is an example code that will create a Matter Device which can be
 * commissioned and controlled from a Matter Environment APP.
 * Additionally the ESP32 will send debug messages indicating the Matter activity.
 * Turning DEBUG Level ON may be useful to following Matter Accessory and Controller messages.
 *
 * The example will create a Matter Contact Sensor Device.
 * begin() creates the endpoint with StateValue open. Call setContact() after
 * Matter.begin() with the real or simulated sensor reading.
 * The Contact Sensor state will be indicated by the onboard LED.
 * The Contact Sensor state will be simulated to change every simulatedSensorInterval.
 *
 * The onboard button can be kept pressed for 5 seconds to decommission the Matter Node.
 * The example will also show the manual commissioning code and QR code to be used in the Matter environment.
 *
 */

// Matter Manager
#include <Arduino.h>
#include <Matter.h>
// List of Matter Endpoints for this Node
// Matter Contact Sensor Endpoint
MatterContactSensor ContactSensor;

// Wi-Fi credentials for this sketch. Fill these in when the board cannot
// commission over BLE (Arduino prebuild on ESP32 / ESP32-S2): the sketch
// joins the AP itself. When Matter commissions over BLE (CHIPoBLE), the
// hub sends SSID and password — leave the placeholders; they are unused.
#define WIFI_SSID     "your-ssid"
#define WIFI_PASSWORD "your-password"

// LED will be used to indicate the Contact Sensor state
// set your board RGB LED pin here
#ifdef RGB_BUILTIN
const uint8_t ledPin = RGB_BUILTIN;
#else
const uint8_t ledPin = 2;  // Set your pin here if the board has no RGB_BUILTIN
#warning "Do not forget to set the RGB LED pin"
#endif

// set your board USER BUTTON pin here - decommissioning only
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.
MatterButton button;

// Simulated hardware toggles every 20 seconds. Replace simulatedHWContactSensor() with a real probe read.
const uint32_t simulatedSensorInterval = 20000;

void setup() {
  // Initialize the USER BUTTON (Boot button) that will be used to decommission the Matter Node
  button.begin(buttonPin);
  // Initialize the LED (light) GPIO and Matter End Point
  pinMode(ledPin, OUTPUT);

  Serial.begin(115200);

// CONFIG_ENABLE_CHIPOBLE=n: sketch starts Wi-Fi here; with CHIPoBLE the hub delivers credentials.
#if !CONFIG_ENABLE_CHIPOBLE
  matterConnectWiFi(WIFI_SSID, WIFI_PASSWORD);
#endif

  // Create the endpoint. Fabric StateValue starts false (open); call setContact() after Matter.begin().
  ContactSensor.begin();
  digitalWrite(ledPin, LOW);  // LED OFF

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  matterWaitUntilReady();
}

bool simulatedHWContactSensor() {
  // Simulated Contact Sensor. Replace this body with a real sensor, e.g. return digitalRead(contactPin);
  static bool contactState = false;
  static uint32_t lastTime = millis();

  if (millis() - lastTime > simulatedSensorInterval) {
    contactState = !contactState;
    lastTime = millis();
  }
  return contactState;
}

void loop() {
  matterRestartIfNoFabric();

  matterButtonEvent_t ev;
  while ((ev = button.poll()) != MATTER_BUTTON_NONE) {
    if (ev == MATTER_BUTTON_LONG_HOLD) {
      Serial.println("Decommissioning Contact Sensor Matter Accessory. It shall be commissioned again.");
      Matter.decommission();
    }
  }

  // Report simulated (or real) hardware to Matter. First call after Matter.begin() applies the current reading.
  bool previous = ContactSensor.getContact();
  ContactSensor.setContact(simulatedHWContactSensor());
  if (ContactSensor.getContact() != previous) {
    Serial.printf("Contact Sensor is %s.\r\n", ContactSensor ? "Closed" : "Open");
  }
  digitalWrite(ledPin, ContactSensor ? HIGH : LOW);

  delay(50);
}