MatterDimmablePlugin

About

The MatterDimmablePlugin class provides a dimmable plugin unit endpoint for Matter networks. This endpoint implements the Matter dimmable plugin standard for controlling power outlets, relays, and other dimmable devices with power level control.

Features: * On/off control * Power level control (Arduino 0-255; Matter CurrentLevel is 1-254, and 255 is the nullable null sentinel) * State persistence support * Callback support for state and level changes * Integration with Home Assistant, Apple Home, Amazon Alexa, and Google Home * Matter standard compliance

Use Cases: * Dimmable smart power outlets * Variable power control * Smart dimmer plugs * Level-controlled device control

API Reference

Constructor

MatterDimmablePlugin

Creates a new Matter dimmable plugin endpoint.

MatterDimmablePlugin();

Initialization

begin

Initializes the Matter dimmable plugin endpoint with optional initial state and level.

bool begin(bool initialState = false, uint8_t level = 64);

  • initialState - Initial on/off state (true = on, false = off, default: false)

  • level - Initial power level (0-255, default: 64 = 25%). 0 is stored as 1; 255 is stored as 254.

This function will return true if successful, false otherwise.

end

Stops processing Matter plugin events.

void end();

On/Off Control

setOnOff

Sets the on/off state of the plugin.

bool setOnOff(bool newState);

  • newState - New state (true = on, false = off)

This function will return true if successful, false otherwise.

getOnOff

Gets the current on/off state of the plugin.

bool getOnOff();

This function will return true if the plugin is on, false if off.

toggle

Toggles the on/off state of the plugin.

bool toggle();

This function will return true if successful, false otherwise.

Level Control

setLevel

Sets the power level of the plugin.

bool setLevel(uint8_t newLevel);

  • newLevel - Power level (0-255). On/off is a separate attribute; 0 clamps to 1 and 255 clamps to 254.

This function will return true if successful, false otherwise.

getLevel

Gets the current power level of the plugin.

uint8_t getLevel();

This function will return the power level (1-254).

Constants

MAX_LEVEL

Arduino full-scale input (255). Matter stores this as 254.

static const uint8_t MAX_LEVEL = 255;

Operators

bool operator

Returns the current on/off state of the plugin.

operator bool();

Example:

if (myPlugin) {
    Serial.println("Plugin is on");
}

Assignment operator

Turns the plugin on or off.

void operator=(bool state);

Example:

myPlugin = true;   // Turn plugin on
myPlugin = false;  // Turn plugin off

Event Handling

onChange

Sets a callback function to be called when any parameter changes.

void onChange(EndPointCB onChangeCB);

  • onChangeCB - Function to call when state changes

The callback signature is:

bool onChangeCallback(bool newState, uint8_t newLevel);

  • newState - New on/off state (true = on, false = off)

  • newLevel - New power level (1-254)

onChangeOnOff

Sets a callback function to be called when the on/off state changes.

void onChangeOnOff(EndPointOnOffCB onChangeCB);

  • onChangeCB - Function to call when on/off state changes

The callback signature is:

bool onChangeCallback(bool newState);

  • newState - New on/off state (true = on, false = off)

onChangeLevel

Sets a callback function to be called when the power level changes.

void onChangeLevel(EndPointLevelCB onChangeCB);

  • onChangeCB - Function to call when level changes

The callback signature is:

bool onChangeCallback(uint8_t newLevel);

  • newLevel - New power level (1-254)

updateAccessory

Updates the state of the plugin using the current Matter Plugin internal state.

void updateAccessory();

This function will call the registered callback with the current state.

Example

Dimmable Plugin

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

// Matter Manager
#include <Arduino.h>
#include <Matter.h>
#include <Preferences.h>

// List of Matter Endpoints for this Node
// Dimmable Plugin Endpoint
MatterDimmablePlugin DimmablePlugin;

// Wi-Fi credentials for this sketch. Fill these in when the board cannot
// commission over BLE (Arduino prebuild on ESP32 / ESP32-S2): the sketch
// joins the AP itself. When Matter commissions over BLE (CHIPoBLE), the
// hub sends SSID and password — leave the placeholders; they are unused.
#define WIFI_SSID     "your-ssid"
#define WIFI_PASSWORD "your-password"

// it will keep last OnOff & Level state stored, using Preferences
Preferences matterPref;
const char *onOffPrefKey = "OnOff";
const char *levelPrefKey = "Level";

// set your board RGB LED pin here
#ifdef RGB_BUILTIN
const uint8_t pluginPin = RGB_BUILTIN;  // Using built-in RGB LED for visualization
#else
const uint8_t pluginPin = 2;  // Set your pin here if your board has not defined RGB_BUILTIN
#warning "Do not forget to set the RGB LED pin"
#endif

// set your board USER BUTTON pin here
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.
MatterButton button;

// Set the RGB LED Plugin output based on the current state and level
bool setPluginState(bool state, uint8_t level) {
  Serial.printf("User Callback :: New Plugin State = %s, Level = %u\r\n", state ? "ON" : "OFF", level);
  if (state) {
    // Plugin is ON - set RGB LED level (0-255 maps to 0-100% power)
#ifdef RGB_BUILTIN
    rgbLedWrite(pluginPin, level, level, level);
#else
    analogWrite(pluginPin, level);
#endif
  } else {
    // Plugin is OFF - turn off output
#ifndef RGB_BUILTIN
    // After analogWrite(), it is necessary to set the GPIO to digital mode first
    pinMode(pluginPin, OUTPUT);
#endif
    digitalWrite(pluginPin, LOW);
  }
  // store last Level and OnOff state for when the Plugin is restarted / power goes off
  matterPref.putUChar(levelPrefKey, level);
  matterPref.putBool(onOffPrefKey, state);
  // This callback must return the success state to Matter core
  return true;
}

void setup() {
  // Initialize the USER BUTTON (Boot button) GPIO that will act as a toggle switch
  button.begin(buttonPin);
  // Initialize the RGB LED (plugin) GPIO
  pinMode(pluginPin, OUTPUT);
  digitalWrite(pluginPin, LOW);  // Start with plugin off

  Serial.begin(115200);

// CONFIG_ENABLE_CHIPOBLE=n: sketch starts Wi-Fi here; with CHIPoBLE the hub delivers credentials.
#if !CONFIG_ENABLE_CHIPOBLE
  matterConnectWiFi(WIFI_SSID, WIFI_PASSWORD);
#endif

  // Initialize Matter EndPoint
  matterPref.begin("MatterPrefs", false);
  // default OnOff state is OFF if not stored before
  bool lastOnOffState = matterPref.getBool(onOffPrefKey, false);
  // default level ~= 25% (64/255)
  uint8_t lastLevel = matterPref.getUChar(levelPrefKey, 64);
  DimmablePlugin.begin(lastOnOffState, lastLevel);
  // set the callback function to handle the Plugin state change
  DimmablePlugin.onChange(setPluginState);

  // lambda functions are used to set the attribute change callbacks
  DimmablePlugin.onChangeOnOff([](bool state) {
    Serial.printf("Plugin OnOff changed to %s\r\n", state ? "ON" : "OFF");
    return true;
  });
  DimmablePlugin.onChangeLevel([](uint8_t level) {
    Serial.printf("Plugin Level changed to %u\r\n", level);
    return true;
  });

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  matterWaitUntilReady();
  Serial.printf("Initial state: %s | level: %u\r\n", DimmablePlugin ? "ON" : "OFF", DimmablePlugin.getLevel());
  DimmablePlugin.updateAccessory();
}

void loop() {
  matterRestartIfNoFabric();

  matterButtonEvent_t ev;
  while ((ev = button.poll()) != MATTER_BUTTON_NONE) {
    if (ev == MATTER_BUTTON_CLICK) {
      Serial.println("User button released. Toggling Plugin!");
      DimmablePlugin.toggle();
    } else if (ev == MATTER_BUTTON_LONG_HOLD) {
      Serial.println("Decommissioning the Plugin Matter Accessory. It shall be commissioned again.");
      DimmablePlugin = false;
      Matter.decommission();
    }
  }
}