MatterOnOffLight

About

The MatterOnOffLight class provides a simple on/off light endpoint for Matter networks. This endpoint implements the Matter lighting standard for basic light control without dimming or color features.

Features: * Simple on/off control * State persistence support * Callback support for state changes * Integration with Home Assistant, Apple Home, Amazon Alexa, and Google Home * Matter standard compliance

Use Cases: * Simple smart lights * On/off switches * Basic lighting control * Smart home automation

API Reference

Constructor

MatterOnOffLight

Creates a new Matter on/off light endpoint.

MatterOnOffLight();

Initialization

begin

Initializes the Matter on/off light endpoint with an optional initial state.

bool begin(bool initialState = false);

initialState - Initial on/off state (true = on, false = off, default: false)

This function will return true if successful, false otherwise.

end

Stops processing Matter light events. This will just stop processing Light Matter events but won’t remove the endpoint.

void end();

On/Off Control

setOnOff

Sets the on/off state of the light.

bool setOnOff(bool newState);

newState - New state (true = on, false = off)

This function will return true if successful, false otherwise.

getOnOff

Gets the current on/off state of the light.

bool getOnOff();

This function will return true if the light is on, false if off.

toggle

Toggles the on/off state of the light.

bool toggle();

This function will return true if successful, false otherwise.

Operators

bool operator

Returns the current on/off state of the light.

operator bool();

Example:

if (myLight) {
    Serial.println("Light is on");
}

Assignment operator

Turns the light on or off.

void operator=(bool state);

Example:

myLight = true;   // Turn light on
myLight = false;  // Turn light off

Event Handling

onChange

Sets a callback function to be called when the light state changes.

void onChange(EndPointCB onChangeCB);

onChangeCB - Function to call when state changes

The callback signature is:

bool onChangeCallback(bool newState);

newState - New on/off state (true = on, false = off)

The callback should return true if the change was handled successfully.

onChangeOnOff

Sets a callback function to be called when the on/off state changes (same as onChange).

void onChangeOnOff(EndPointCB onChangeCB);

onChangeCB - Function to call when state changes

updateAccessory

Updates the state of the light using the current Matter Light internal state. It is necessary to set a user callback function using onChange() to handle the physical light state.

void updateAccessory();

This function will call the registered callback with the current state.

Example

Basic On/Off Light

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

// Matter Manager
#include <Arduino.h>
#include <Matter.h>
#include <Preferences.h>

// Wi-Fi credentials for this sketch. Fill these in when the board cannot
// commission over BLE (Arduino prebuild on ESP32 / ESP32-S2): the sketch
// joins the AP itself. When Matter commissions over BLE (CHIPoBLE), the
// hub sends SSID and password — leave the placeholders; they are unused.
#define WIFI_SSID     "your-ssid"
#define WIFI_PASSWORD "your-password"

// List of Matter Endpoints for this Node
// On/Off Light Endpoint
MatterOnOffLight OnOffLight;

// it will keep last OnOff state stored, using Preferences
Preferences matterPref;
const char *onOffPrefKey = "OnOff";

// set your board LED pin here
#ifdef LED_BUILTIN
const uint8_t ledPin = LED_BUILTIN;
#else
const uint8_t ledPin = 2;  // Set your pin here if your board has not defined LED_BUILTIN
#warning "Do not forget to set the LED pin"
#endif

// set your board USER BUTTON pin here
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.
MatterButton button;

// Matter Protocol Endpoint Callback
bool setLightOnOff(bool state) {
  Serial.printf("User Callback :: New Light State = %s\r\n", state ? "ON" : "OFF");
  if (state) {
    digitalWrite(ledPin, HIGH);
  } else {
    digitalWrite(ledPin, LOW);
  }
  // store last OnOff state for when the Light is restarted / power goes off
  matterPref.putBool(onOffPrefKey, state);
  // This callback must return the success state to Matter core
  return true;
}

void setup() {
  // Initialize the USER BUTTON (Boot button) GPIO that will act as a toggle switch
  button.begin(buttonPin);
  // Initialize the LED (light) GPIO and Matter End Point
  pinMode(ledPin, OUTPUT);

  Serial.begin(115200);

// CONFIG_ENABLE_CHIPOBLE=n: sketch starts Wi-Fi here; with CHIPoBLE the hub delivers credentials.
#if !CONFIG_ENABLE_CHIPOBLE
  matterConnectWiFi(WIFI_SSID, WIFI_PASSWORD);
#endif

  // Initialize Matter EndPoint
  matterPref.begin("MatterPrefs", false);
  bool lastOnOffState = matterPref.getBool(onOffPrefKey, true);
  OnOffLight.begin(lastOnOffState);
  OnOffLight.onChange(setLightOnOff);

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  matterWaitUntilReady();
  Serial.printf("Initial state: %s\r\n", OnOffLight.getOnOff() ? "ON" : "OFF");
  OnOffLight.updateAccessory();
}

void loop() {
  matterRestartIfNoFabric();

  matterButtonEvent_t ev;
  while ((ev = button.poll()) != MATTER_BUTTON_NONE) {
    if (ev == MATTER_BUTTON_CLICK) {
      Serial.println("User button released. Toggling Light!");
      OnOffLight.toggle();
    } else if (ev == MATTER_BUTTON_LONG_HOLD) {
      Serial.println("Decommissioning the Light Matter Accessory. It shall be commissioned again.");
      OnOffLight.setOnOff(false);
      Matter.decommission();
    }
  }
}