MatterDimmableLight

About

The MatterDimmableLight class provides a dimmable light endpoint for Matter networks. This endpoint implements the Matter lighting standard for lights with brightness control.

Features: * On/off control * Brightness level control (0-255) * State persistence support * Callback support for state and brightness changes * Integration with Apple HomeKit, Amazon Alexa, and Google Home * Matter standard compliance

Use Cases: * Dimmable smart lights * Brightness control switches * Smart home lighting automation * Variable brightness lighting

API Reference

Constructor

MatterDimmableLight

Creates a new Matter dimmable light endpoint.

MatterDimmableLight();

Initialization

begin

Initializes the Matter dimmable light endpoint with optional initial state and brightness.

bool begin(bool initialState = false, uint8_t brightness = 64);

initialState - Initial on/off state (true = on, false = off, default: false)
brightness - Initial brightness level (0-255, default: 64 = 25%)

This function will return true if successful, false otherwise.

end

Stops processing Matter light events.

void end();

On/Off Control

setOnOff

Sets the on/off state of the light.

bool setOnOff(bool newState);

newState - New state (true = on, false = off)

This function will return true if successful, false otherwise.

getOnOff

Gets the current on/off state of the light.

bool getOnOff();

This function will return true if the light is on, false if off.

toggle

Toggles the on/off state of the light.

bool toggle();

This function will return true if successful, false otherwise.

Brightness Control

setBrightness

Sets the brightness level of the light.

bool setBrightness(uint8_t newBrightness);

newBrightness - New brightness level (0-255, where 0 = off, 255 = maximum brightness)

This function will return true if successful, false otherwise.

getBrightness

Gets the current brightness level of the light.

uint8_t getBrightness();

This function will return the brightness level (0-255).

Constants

MAX_BRIGHTNESS

Maximum brightness value constant.

static const uint8_t MAX_BRIGHTNESS = 255;

Operators

bool operator

Returns the current on/off state of the light.

operator bool();

Assignment operator

Turns the light on or off.

void operator=(bool state);

Event Handling

onChange

Sets a callback function to be called when any parameter changes.

void onChange(EndPointCB onChangeCB);

onChangeCB - Function to call when state changes

The callback signature is:

bool onChangeCallback(bool newState, uint8_t newBrightness);

newState - New on/off state
newBrightness - New brightness level (0-255)

onChangeOnOff

Sets a callback function to be called when the on/off state changes.

void onChangeOnOff(EndPointOnOffCB onChangeCB);

onChangeCB - Function to call when on/off state changes

The callback signature is:

bool onChangeCallback(bool newState);

onChangeBrightness

Sets a callback function to be called when the brightness level changes.

void onChangeBrightness(EndPointBrightnessCB onChangeCB);

onChangeCB - Function to call when brightness changes

The callback signature is:

bool onChangeCallback(uint8_t newBrightness);

updateAccessory

Updates the state of the light using the current Matter Light internal state.

void updateAccessory();

Example

Dimmable Light

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at

//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

// Matter Manager
#include <Matter.h>
#if !CONFIG_ENABLE_CHIPOBLE
// if the device can be commissioned using BLE, WiFi is not used - save flash space
#include <WiFi.h>
#endif
#include <Preferences.h>

// List of Matter Endpoints for this Node
// Dimmable Light Endpoint
MatterDimmableLight DimmableLight;

// CONFIG_ENABLE_CHIPOBLE is enabled when BLE is used to commission the Matter Network
#if !CONFIG_ENABLE_CHIPOBLE
// WiFi is manually set and started
const char *ssid = "your-ssid";          // Change this to your WiFi SSID
const char *password = "your-password";  // Change this to your WiFi password
#endif

// it will keep last OnOff & Brightness state stored, using Preferences
Preferences matterPref;
const char *onOffPrefKey = "OnOff";
const char *brightnessPrefKey = "Brightness";

// set your board RGB LED pin here
#ifdef RGB_BUILTIN
const uint8_t ledPin = RGB_BUILTIN;
#else
const uint8_t ledPin = 2;  // Set your pin here if your board has not defined LED_BUILTIN
#warning "Do not forget to set the RGB LED pin"
#endif

// set your board USER BUTTON pin here
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.

// Button control
uint32_t button_time_stamp = 0;                // debouncing control
bool button_state = false;                     // false = released | true = pressed
const uint32_t debouceTime = 250;              // button debouncing time (ms)
const uint32_t decommissioningTimeout = 5000;  // keep the button pressed for 5s, or longer, to decommission

// Set the RGB LED Light based on the current state of the Dimmable Light
bool setLightState(bool state, uint8_t brightness) {
  if (state) {
#ifdef RGB_BUILTIN
    rgbLedWrite(ledPin, brightness, brightness, brightness);
#else
    analogWrite(ledPin, brightness);
#endif
  } else {
#ifndef RGB_BUILTIN
    // after analogWrite(), it is necessary to set the GPIO to digital mode first
    pinMode(ledPin, OUTPUT);
#endif
    digitalWrite(ledPin, LOW);
  }
  // store last Brightness and OnOff state for when the Light is restarted / power goes off
  matterPref.putUChar(brightnessPrefKey, brightness);
  matterPref.putBool(onOffPrefKey, state);
  // This callback must return the success state to Matter core
  return true;
}

void setup() {
  // Initialize the USER BUTTON (Boot button) GPIO that will act as a toggle switch
  pinMode(buttonPin, INPUT_PULLUP);
  // Initialize the LED (light) GPIO and Matter End Point
  pinMode(ledPin, OUTPUT);

  Serial.begin(115200);

// CONFIG_ENABLE_CHIPOBLE is enabled when BLE is used to commission the Matter Network
#if !CONFIG_ENABLE_CHIPOBLE
  // We start by connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);
  // Manually connect to WiFi
  WiFi.begin(ssid, password);
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\r\nWiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  delay(500);
#endif

  // Initialize Matter EndPoint
  matterPref.begin("MatterPrefs", false);
  // default OnOff state is ON if not stored before
  bool lastOnOffState = matterPref.getBool(onOffPrefKey, true);
  // default brightness ~= 6% (15/255)
  uint8_t lastBrightness = matterPref.getUChar(brightnessPrefKey, 15);
  DimmableLight.begin(lastOnOffState, lastBrightness);
  // set the callback function to handle the Light state change
  DimmableLight.onChange(setLightState);

  // lambda functions are used to set the attribute change callbacks
  DimmableLight.onChangeOnOff([](bool state) {
    Serial.printf("Light OnOff changed to %s\r\n", state ? "ON" : "OFF");
    return true;
  });
  DimmableLight.onChangeBrightness([](uint8_t level) {
    Serial.printf("Light Brightness changed to %d\r\n", level);
    return true;
  });

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  // This may be a restart of a already commissioned Matter accessory
  if (Matter.isDeviceCommissioned()) {
    Serial.println("Matter Node is commissioned and connected to the network. Ready for use.");
    Serial.printf("Initial state: %s | brightness: %d\r\n", DimmableLight ? "ON" : "OFF", DimmableLight.getBrightness());
    // configure the Light based on initial on-off state and brightness
    DimmableLight.updateAccessory();
  }
}

void loop() {
  // Check Matter Light Commissioning state, which may change during execution of loop()
  if (!Matter.isDeviceCommissioned()) {
    Serial.println("");
    Serial.println("Matter Node is not commissioned yet.");
    Serial.println("Initiate the device discovery in your Matter environment.");
    Serial.println("Commission it to your Matter hub with the manual pairing code or QR code");
    Serial.printf("Manual pairing code: %s\r\n", Matter.getManualPairingCode().c_str());
    Serial.printf("QR code URL: %s\r\n", Matter.getOnboardingQRCodeUrl().c_str());
    // waits for Matter Light Commissioning.
    uint32_t timeCount = 0;
    while (!Matter.isDeviceCommissioned()) {
      delay(100);
      if ((timeCount++ % 50) == 0) {  // 50*100ms = 5 sec
        Serial.println("Matter Node not commissioned yet. Waiting for commissioning.");
      }
    }
    Serial.printf("Initial state: %s | brightness: %d\r\n", DimmableLight ? "ON" : "OFF", DimmableLight.getBrightness());
    // configure the Light based on initial on-off state and brightness
    DimmableLight.updateAccessory();
    Serial.println("Matter Node is commissioned and connected to the network. Ready for use.");
  }

  // A button is also used to control the light
  // Check if the button has been pressed
  if (digitalRead(buttonPin) == LOW && !button_state) {
    // deals with button debouncing
    button_time_stamp = millis();  // record the time while the button is pressed.
    button_state = true;           // pressed.
  }

  // Onboard User Button is used as a Light toggle switch or to decommission it
  uint32_t time_diff = millis() - button_time_stamp;
  if (digitalRead(buttonPin) == HIGH && button_state && time_diff > debouceTime) {
    // Toggle button is released - toggle the light
    Serial.println("User button released. Toggling Light!");
    DimmableLight.toggle();  // Matter Controller also can see the change
    button_state = false;    // released
  }

  // Onboard User Button is kept pressed for longer than 5 seconds in order to decommission matter node
  if (button_state && time_diff > decommissioningTimeout) {
    Serial.println("Decommissioning the Light Matter Accessory. It shall be commissioned again.");
    DimmableLight = false;  // turn the light off
    Matter.decommission();
    button_time_stamp = millis();  // avoid running decommissining again, reboot takes a second or so
  }
}