MatterPressureSensor

About

The MatterPressureSensor class provides a pressure sensor endpoint for Matter networks. This endpoint implements the Matter pressure sensing standard for read-only pressure reporting.

Features: * Pressure measurement reporting in hectopascals (hPa) * Read-only sensor (no control functionality) * Automatic pressure updates * Integration with Home Assistant, Apple Home, Amazon Alexa, and Google Home * Matter standard compliance

Use Cases: * Atmospheric pressure monitoring * Weather stations * Barometric pressure sensors * Pressure logging * Smart home weather monitoring

API Reference

Constructor

MatterPressureSensor

Creates a new Matter pressure sensor endpoint.

MatterPressureSensor();

Initialization

begin

Initializes the Matter pressure sensor endpoint with an initial pressure value.

bool begin(double pressure = 0.00);

pressure - Initial pressure in hectopascals (hPa, default: 0.00)

This function will return true if successful, false otherwise.

Note: Typical atmospheric pressure at sea level is around 1013.25 hPa. Pressure values typically range from 950-1050 hPa.

end

Stops processing Matter pressure sensor events.

void end();

Pressure Control

setPressure

Sets the reported pressure value.

bool setPressure(double pressure);

pressure - Pressure in hectopascals (hPa)

This function will return true if successful, false otherwise.

getPressure

Gets the current reported pressure value.

double getPressure();

This function will return the pressure in hectopascals (hPa).

Operators

double operator

Returns the current pressure.

operator double();

Example:

double pressure = mySensor;  // Get current pressure

Assignment operator

Sets the pressure value.

void operator=(double pressure);

Example:

mySensor = 1013.25;  // Set pressure to 1013.25 hPa

Example

Pressure Sensor

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

/*
 * This example is an example code that will create a Matter Device which can be
 * commissioned and controlled from a Matter Environment APP.
 * Additionally the ESP32 will send debug messages indicating the Matter activity.
 * Turning DEBUG Level ON may be useful to following Matter Accessory and Controller messages.
 */

// Matter Manager
#include <Arduino.h>
#include <Matter.h>
// List of Matter Endpoints for this Node
// Matter Pressure Sensor Endpoint
MatterPressureSensor SimulatedPressureSensor;

// Wi-Fi credentials for this sketch. Fill these in when the board cannot
// commission over BLE (Arduino prebuild on ESP32 / ESP32-S2): the sketch
// joins the AP itself. When Matter commissions over BLE (CHIPoBLE), the
// hub sends SSID and password — leave the placeholders; they are unused.
#define WIFI_SSID     "your-ssid"
#define WIFI_PASSWORD "your-password"

// set your board USER BUTTON pin here - decommissioning button
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.
MatterButton button;

// Simulate a pressure sensor - add your preferred pressure sensor library code here
float getSimulatedPressure() {
  // The Endpoint implementation keeps an uint16_t as internal value information,
  // which stores data in hPa (pressure measurement unit)
  static float simulatedPressureHWSensor = 950;

  // it will increase from 950 to 1100 hPa in steps of 10 hPa to simulate a pressure sensor
  simulatedPressureHWSensor = simulatedPressureHWSensor + 10;
  if (simulatedPressureHWSensor > 1100) {
    simulatedPressureHWSensor = 950;
  }

  return simulatedPressureHWSensor;
}

void setup() {
  // Initialize the USER BUTTON (Boot button) that will be used to decommission the Matter Node
  button.begin(buttonPin);

  Serial.begin(115200);

// CONFIG_ENABLE_CHIPOBLE=n: sketch starts Wi-Fi here; with CHIPoBLE the hub delivers credentials.
#if !CONFIG_ENABLE_CHIPOBLE
  matterConnectWiFi(WIFI_SSID, WIFI_PASSWORD);
#endif

  // set initial pressure sensor measurement
  // Simulated Sensor - it shall initially print 900hPa and then move to the 950 to 1100 hPa as pressure range
  SimulatedPressureSensor.begin(900.00);

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  matterWaitUntilReady();
}

void loop() {
  matterRestartIfNoFabric();

  static uint32_t timeCounter = 0;

  // Print the current pressure value every 5s
  if (!(timeCounter++ % 10)) {  // delaying for 500ms x 10 = 5s
    // Print the current pressure value
    Serial.printf("Current Pressure is %.02fhPa\r\n", SimulatedPressureSensor.getPressure());
    // Update Pressure from the (Simulated) Hardware Sensor
    // Matter APP shall display the updated pressure.
    SimulatedPressureSensor.setPressure(getSimulatedPressure());
  }

  matterButtonEvent_t ev;
  while ((ev = button.poll()) != MATTER_BUTTON_NONE) {
    if (ev == MATTER_BUTTON_LONG_HOLD) {
      Serial.println("Decommissioning Pressure Sensor Matter Accessory. It shall be commissioned again.");
      Matter.decommission();
    }
  }

  delay(500);
}