MatterTemperatureSensor

About

The MatterTemperatureSensor class provides a temperature sensor endpoint for Matter networks. This endpoint implements the Matter temperature sensing standard for read-only temperature reporting.

Features: * Temperature measurement reporting in Celsius * 1/100th degree Celsius precision * Read-only sensor (no control functionality) * Automatic temperature updates * Integration with Home Assistant, Apple Home, Amazon Alexa, and Google Home * Matter standard compliance

Use Cases: * Room temperature monitoring * Weather stations * HVAC systems * Temperature logging * Smart home climate monitoring

API Reference

Constructor

MatterTemperatureSensor

Creates a new Matter temperature sensor endpoint.

MatterTemperatureSensor();

Initialization

begin

Initializes the Matter temperature sensor endpoint with an initial temperature value.

bool begin(double temperature = 0.00);

temperature - Initial temperature in Celsius (default: 0.00). Matter MeasuredValue is int16 hundredths (−327.68…327.67 °C).

This function will return true if successful, false if the value is out of range or creation fails.

Note: The implementation stores temperature with 1/100th degree Celsius precision internally.

end

Stops processing Matter temperature sensor events.

void end();

Temperature Control

setTemperature

Sets the reported temperature value.

bool setTemperature(double temperature);

temperature - Temperature in Celsius

This function will return true if successful, false otherwise.

Note: Temperature is stored with 1/100th degree Celsius precision. Values outside −327.68…327.67 °C return false (int16 overflow).

getTemperature

Gets the current reported temperature value.

double getTemperature();

This function will return the temperature in Celsius with 1/100th degree precision.

Operators

double operator

Returns the current temperature.

operator double();

Example:

double temp = mySensor;  // Get current temperature

Assignment operator

Sets the temperature value.

void operator=(double temperature);

Example:

mySensor = 25.5;  // Set temperature to 25.5°C

Example

Temperature Sensor

// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

/*
 * This example is an example code that will create a Matter Device which can be
 * commissioned and controlled from a Matter Environment APP.
 * Additionally the ESP32 will send debug messages indicating the Matter activity.
 * Turning DEBUG Level ON may be useful to following Matter Accessory and Controller messages.
 */

// Matter Manager
#include <Arduino.h>
#include <Matter.h>
// List of Matter Endpoints for this Node
// Matter Temperature Sensor Endpoint
MatterTemperatureSensor SimulatedTemperatureSensor;

// Wi-Fi credentials for this sketch. Fill these in when the board cannot
// commission over BLE (Arduino prebuild on ESP32 / ESP32-S2): the sketch
// joins the AP itself. When Matter commissions over BLE (CHIPoBLE), the
// hub sends SSID and password — leave the placeholders; they are unused.
#define WIFI_SSID     "your-ssid"
#define WIFI_PASSWORD "your-password"

// set your board USER BUTTON pin here - decommissioning button
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.
MatterButton button;

// Simulate a temperature sensor - add your preferred temperature sensor library code here
float getSimulatedTemperature() {
  // The Endpoint implementation keeps an int16_t as internal value information,
  // which stores data in 1/100th Celsius.
  static float simulatedTempHWSensor = -10.0;

  // it will increase from -10C to 10C in 0.5C steps to simulate a temperature sensor
  simulatedTempHWSensor = simulatedTempHWSensor + 0.5;
  if (simulatedTempHWSensor > 10) {
    simulatedTempHWSensor = -10;
  }

  return simulatedTempHWSensor;
}

void setup() {
  // Initialize the USER BUTTON (Boot button) that will be used to decommission the Matter Node
  button.begin(buttonPin);

  Serial.begin(115200);

// CONFIG_ENABLE_CHIPOBLE=n: sketch starts Wi-Fi here; with CHIPoBLE the hub delivers credentials.
#if !CONFIG_ENABLE_CHIPOBLE
  matterConnectWiFi(WIFI_SSID, WIFI_PASSWORD);
#endif

  // set initial temperature sensor measurement
  // Simulated Sensor - it shall initially print -25C and then move to the -10C to 10C range
  SimulatedTemperatureSensor.begin(-25.00);

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  matterWaitUntilReady();
}

void loop() {
  matterRestartIfNoFabric();

  static uint32_t timeCounter = 0;

  // Print the current temperature value every 5s
  if (!(timeCounter++ % 10)) {  // delaying for 500ms x 10 = 5s
    // Print the current temperature value
    Serial.printf("Current Temperature is %.02fC\r\n", SimulatedTemperatureSensor.getTemperature());
    // Update Temperature from the (Simulated) Hardware Sensor
    // Matter APP shall display the updated temperature.
    SimulatedTemperatureSensor.setTemperature(getSimulatedTemperature());
  }

  matterButtonEvent_t ev;
  while ((ev = button.poll()) != MATTER_BUTTON_NONE) {
    if (ev == MATTER_BUTTON_LONG_HOLD) {
      Serial.println("Decommissioning Temperature Sensor Matter Accessory. It shall be commissioned again.");
      Matter.decommission();
    }
  }

  delay(500);
}